home *** CD-ROM | disk | FTP | other *** search
/ PD ROM 1 / PD ROM Volume I - Macintosh Software from BMUG (1988).iso / Programming / Languages / Assembler / lister.asm < prev    next >
Encoding:
Assembly Source File  |  1987-08-23  |  28.7 KB  |  1,162 lines  |  [TEXT/ttxt]
  1. ;****************************************************************
  2.  
  3. ; Copyright (c)    1985 by    Dave McWherter
  4.  
  5. ; This a simple    print application that just reads a text file
  6. ; and sends it as ASCII    codes to the serial printer driver.
  7.  
  8. ;It also shows off some    of the features    of the new McAsm assembler
  9. ;and McLink linker. (That means    that this file can't be    assembled
  10. ;by MDS    or MACASM, but at least    the structure of the program and
  11. ;the code itself is a useful example.) McAsm is    available from me
  12. ;directly at the following address:
  13.  
  14. ; Author: Dave McWherter - 70057,1612
  15. ;      2151 Brown Ave.
  16. ;      Bensalem, PA 19020
  17. ;      215-639-8764
  18.  
  19. ;****************************************************************
  20.  
  21. ; File = LIST.ASM
  22.  
  23.     title    "File lister application   $"    timestamp in title
  24.     name    LIST        our module ID
  25.     prtr    "/E/$45"    set Imagewriter    for ELITE
  26.  
  27. ;****************************************************************
  28. ;Configure our application file:
  29.  
  30.     ftype    'APPL'        file type
  31.     fsign    'List'        file signature
  32.     a5off    $100        start a5 offset    data $100 below    a5
  33.  
  34. ;****************************************************************
  35. ;Assembly setup    stuff:
  36.  
  37.     mexp    0        don't expand macros
  38.     texp    0        don't expand text statements
  39.  
  40. ;****************************************************************
  41. ;Include traps definitions (with listing turned    off):
  42.     list    0
  43.     
  44.     incl    "trapdef.asm"
  45.  
  46.     list    1
  47.  
  48. ;****************************************************************
  49. ; Structure of File Manager parameter block:
  50.  
  51.         dsec    0
  52. ioLink        ds.l    1    queue link in header
  53. ioType        ds.w    1    type for safety    check
  54. ioTrap        ds.w    1    the trap
  55. ioCmdAddr    ds.l    1    address    to dispatch to
  56.  
  57. ioCompletion    ds.l    1    completion routine
  58. ioResult    ds.w    1    I/O result code
  59. ioFileName    ds.l    1    file name pointer
  60. ioVRefNum    equ    *    volume refnum
  61. ioDrvNum    ds.w    1    drive number
  62. ioRefNum    ds.w    1    file reference number
  63.  
  64. csCode        equ    *    control/status code [word]
  65. ioFileType    ds.b    1    specified along    with FileName
  66. ioPermssn    ds.b    1    permissions
  67.  
  68. csParam        equ    *    operation-defined parameters [20 bytes]
  69. ioOwnBuf    ds.l    1    "private" 522-byte buffer
  70.  
  71. ioBuffer    ds.l    1    data buffer
  72. ioByteCount    ds.l    1    requested byte count
  73. ioNumDone    ds.l    1    actual byte count completed
  74.  
  75. ioPosMode    ds.w    1    initial    file positioning mode/eol char
  76. ioPosOffset    ds.l    1    file position offset
  77.         dend
  78.  
  79. ioFQElSize    equ    $50    length of I/O parameter    block
  80.  
  81. ;These are all used as indexes off of A0, so if    we 'BASE' them we
  82. ;don't have to type the    '(a0)'.    In other words,    'clr.w ioDrvNum'
  83. ;will be equivalent to 'clr.w ioDrvNum(a0)'.
  84.  
  85.     base    a0,ioLink,ioType,ioTrap,ioCmdAddr
  86.     base    a0,ioCompletion,ioResult,ioFileName
  87.     base    a0,ioVRefNum,ioDrvNum,ioRefNum,csCode
  88.     base    a0,ioFileType,ioPermssn,csParam,ioOwnBuf
  89.     base    a0,ioBuffer,ioByteCount,ioNumDone
  90.     base    a0,ioPosMode,ioPosOffset
  91.  
  92. ;****************************************************************
  93. ;This is our variable storage area off of A5:
  94.  
  95.         a5sec        start of a5 offset data
  96. DiskParms    equ    *    disk I/O parameter block:
  97.         ds.b    IOFQElSize
  98.  
  99. PrtOutParms    equ    *    printer    I/O parameter block:
  100.         ds.b    IOFQElSize
  101.  
  102. ByteBuffer    ds.b    1    a one-byte buffer
  103.         ds.b    1    align to even boundary for next:
  104.  
  105. EventRecord    equ    *    GetNextEvent's result:
  106. EventType    ds.w    1
  107. EventMessage    ds.l    1
  108. EventTime    ds.l    1
  109. EventLocation    ds.l    1
  110. EventModifiers    ds.w    1
  111.  
  112. WindowPtr    ds.l    1    FindWindow's result
  113.  
  114. MenuHandle    ds.l    1
  115. MenuItem    ds.w    1
  116.  
  117. SFReply        equ    *    reply record from Std File package:
  118. SFGood        ds.b    1
  119. SFCopy        ds.b    1
  120. SFType        ds.b    4
  121. SFVRefNum    ds.w    1
  122. SFVersion    ds.w    1
  123. SFName        ds.b    64
  124.  
  125. ItemHit        ds.w    1    Dialog item hit    result
  126.  
  127. DialogPtr    ds.l    1    Dialog's pointer
  128. DStorage    ds.w    $AA    Dialog's storage area
  129. ItemHandle    ds.l    1    a dialog item's    handle
  130. ItemType    ds.w    1    a dialog item's    type
  131. ItemBox        ds.b    8    a dialog item's    rectangle
  132.  
  133. DeskName    ds.w    16    name of    desk accessory selected
  134.  
  135. NewStyle    ds.w    1    the newly selected style no.
  136. NewOption    ds.w    1    the newly selected option no.
  137. Column        ds.w    1    current    column no.
  138. PageLines    ds.w    1    no. of lines printed on    a page
  139.  
  140.         a5end
  141.  
  142. ;All of    these are indexed by A5. Since we defined them in an
  143. ;'A5SEC', the assembler    will automatically add the '(a5)' to
  144. ;these variables everytime we use them.    In other words,
  145. ;'lea Diskparms,a0' will be equivalent to 'lea DiskParms(a5),a0'.
  146.  
  147. ;****************************************************************
  148. ; Start    up by initializing the managers:
  149.  
  150.     loc
  151. Start    pea    -4(a5)        space For Quickdraw's use
  152.     _InitGraf        initialize QuickDraw
  153.     _InitFonts        initialize Font    Manager
  154.     _InitWindows        initialize Window Manager
  155.     _InitMenus        initialize Menu    Manager
  156.  
  157.     clr.l    -(sp)        put zero on stack for restart procecdure
  158.     _InitDialogs        initialize Dialog Manager
  159.     _TEInit            initialize Text    Edit
  160.  
  161. ;Set up    our menus:
  162.  
  163.     moveq    #1,d1        install    our Apple menu
  164.     bsr    InstallMenu
  165.     move.l    d1,-(sp)    new menu handle    to stack
  166.     move.l    #'DRVR',-(sp)    add desk accessories to    the Apple menu
  167.  
  168.     _AddResMenu
  169.  
  170.     moveq    #2,d1        install    our File menu
  171.     bsr    InstallMenu
  172.  
  173.     moveq    #3,d1        install    our Style menu
  174.     bsr    InstallMenu
  175.  
  176.     moveq    #4,d1        install    our Options menu
  177.     bsr    InstallMenu
  178.  
  179.     _DrawMenuBar        draw the new menu bar
  180.  
  181. ;Other misc. initialization:
  182.  
  183.     move.l    #$0000FFFF,d0    flush all pending events
  184.  
  185.     _FlushEvents
  186.     _InitCursor        init cursor to arrow
  187.  
  188. ;Clear out our I/O device control blocks:
  189.  
  190.     lea    DiskParms,a0
  191.     move.w    #IOFQElSize*2-1,d0
  192. .clr    clr.b    (a0)+
  193.     dbra    d0,.clr
  194.  
  195. ;****************************************************************
  196. ; Main event loop:
  197.  
  198. WaitForEvent
  199.     _SystemTask        update disk accessories    often
  200.  
  201. ;Get any waiting events:
  202.  
  203.     clr.w    -(sp)        clear space for    function result
  204.     move.w    #$FFFF,-(sp)    look for any event
  205.     pea    EventRecord    where to put event result
  206.     _GetNextEvent        any waiting events ?
  207.     move.w    (sp)+,d0
  208.     beq    WaitForEvent    nope - keep looping
  209.  
  210.     move.w    EventType,d0    is it mouse down ?
  211.     cmp.w    #1,d0
  212.     bne    WaitForEvent    no - ignore whatever
  213.     bra.s    MouseDown    yes - go handle    it
  214.  
  215. ;****************************************************************
  216. ; Common exit routine from menu    selections:
  217.  
  218. SelectionExit
  219.     bsr    UnhighlightMenu    unhighlight selected menu title
  220.     bra    WaitForEvent
  221.  
  222. ;****************************************************************
  223. ; Find out where the mouse is down at:
  224.  
  225. MouseDown
  226.     clr.w    -(sp)        make space for integer result
  227.     move.l    EventLocation,-(sp)    ;pass mouse point
  228.     pea    WindowPtr    where to store result window ptr
  229.     _FindWindow        find window where mouse    was
  230.     move.w    (sp)+,d0    get result off stack
  231.  
  232.     cmpi.b    #2,d0        in a system window ?
  233.     beq    SystemWindow    yes
  234.     cmpi.b    #1,d0        in the menu bar    ?
  235.     bne    WaitForEvent    no - ignore it
  236.  
  237. ;****************************************************************
  238. ; Mouse    was pressed in the Menu    Bar:
  239.  
  240. MenuBar
  241.     clr.l    -(sp)        make space for function    result
  242.     move.l    EventLocation,-(sp)    ;pass mouse loc as parameter
  243.     _MenuSelect        menu item selected ?
  244.     move.w    (sp)+,d1       maybe - pop menu ID
  245.     move.w    (sp)+,d2           and menu item number
  246.     move.w    d2,MenuItem    save menu item no.
  247.  
  248.     cmpi.w    #1,d1        branch based on    which menu
  249.     beq.s    AppleMenu
  250.     cmpi.w    #2,d1
  251.     beq    FileMenu
  252.     cmpi.w    #3,d1
  253.     beq    StyleMenu
  254.     cmpi.w    #4,d1
  255.     beq    OptionMenu
  256.     bra    WaitForEvent    ignore if not a    menu we    know
  257.  
  258. ; ****************************************************************
  259. ;  Handle a selection in    Apple menu:
  260.  
  261. AppleMenu
  262.     cmpi.w    #1,d2        is it About ?
  263.     beq    About        yes
  264.  
  265. ;Else it must be a desk accessory menu    item:
  266.  
  267.     moveq    #1,d1        get handle to Menu 1
  268.     bsr    GetMenuHandle
  269. ;                menu handle is    on stack
  270.     move.w    MenuItem,-(sp)    also pass menu's item no.
  271.     pea    DeskName    where to put result text
  272.     _GetItem        get desk accessory name (menu text)
  273.  
  274.     clr.w    -(sp)        make space for    function result
  275.     pea    DeskName    pass desk acc.    name as    param
  276.     _OpenDeskAcc        open the desk acc.
  277.     move.w    (sp)+,d0    clear result from stack
  278.     bra    SelectionExit
  279.  
  280. ;****************************************************************
  281. ; User    has selected our 'About...' menu item:
  282.  
  283. About
  284.     clr.l    -(sp)         make space for    dialog handle result
  285.     move.w    #1,-(sp)     get dialog no.    1 from resc file
  286.     pea    Dstorage
  287.     move.l    #-1,-(sp)     put it    in front of all    other windows
  288.  
  289.     _GetNewDialog
  290. ;                 rtns dialog ptr on stack
  291.     move.l    (sp),-(sp)     we'll need the    ptr again later
  292.     _SetPort         make the dialog the current port
  293.  
  294.     clr.l    -(sp)         no filter procedure
  295.     pea    ItemHit        where to store    result
  296.     _ModalDialog         handle    events in the dialog box
  297.  
  298. ;                 (dialog ptr is    on stack)
  299.     _CloseDialog         whatever the hit was, close it
  300.     bra    SelectionExit
  301.  
  302. ;****************************************************************
  303. ; Handle a selection in our File menu:
  304.  
  305. FileMenu
  306.     cmpi.w    #1,d2         is it Listing ?
  307.     beq    Listing        yes
  308.     cmpi.w    #2,d2         is it Quit ?
  309.     beq    Quit         yes
  310.     bra    WaitForEvent     should    never happen
  311.  
  312. ;****************************************************************
  313.  ; User    has selected 'Listing':
  314.  
  315.     loc
  316. Listing
  317.  
  318. ;Use the standard dialog box to get the filename:
  319.  
  320.     move.w    #80,-(sp)     where to put dialog box
  321.     move.w    #80,-(sp)
  322.     pea    NulStr         docs say not needed, but I can't
  323. ;                   get it to work without a string!
  324.     clr.l    -(sp)         no filter proc
  325.     move.w    #-1,-(sp)     display all file types
  326.     clr.l    -(sp)         no type table
  327.     clr.l    -(sp)         no dialog hook
  328.     pea    SFReply     where to put reply result
  329.     move.w    #2,-(sp)     selector for SFGetFile
  330.     _Pack3                in package 3
  331.  
  332.     move.b    SFGood,d0     did they cancel it ?
  333.     beq    .Exit     yes
  334.  
  335. ;Open the file:
  336.  
  337.     lea    DiskParms,a0     setup ptr to I/O parameter block
  338.     lea    SFName,a1     setup ptr to the name
  339.     move.l    a1,ioFileName
  340.     move.w    SFVRefNum,ioVRefNum     setup vol refnum
  341.  
  342.     move.b    #1,ioPermssn     read only permission
  343.  
  344.     _Open             open the file
  345.     tst.w    d0         successful open ?
  346.     bne    .Exit         no
  347.  
  348. ;Open the serial output driver:
  349.  
  350.     lea    PrtOutParms,a0
  351.     move.w    PortNum,d0     which port ?
  352.     cmpi.w    #2,d0
  353.     beq.s    .PortB     B
  354.  
  355. .PortA    lea    AOutStr,a1
  356.     bra.s    .Open
  357.  
  358. .PortB    lea    BOutStr,a1
  359.  
  360. .Open    move.l    a1,ioFileName
  361.     _Open
  362.     tst.w    d0         successful open ?
  363.     bne.s    .Close         no
  364.  
  365.     bsr    DisplayAbortBox     display the abort/pause dialog
  366.     bsr    StyleToPrinter     send style escape codes to printer
  367.     clr.w    Column         init column no.
  368.  
  369. NewPage    clr.w    PageLines     init page line    counter
  370.  
  371. .Loop    _SystemTask         update    desk accessories often
  372.     bsr    CheckAbort     check for abort or pause
  373.     bcs.s    .Done2         is abort - quit
  374.  
  375.     bsr    ReadByte     read bytes
  376.     bcs.s    .Done         until eof or error
  377.     bsr    PrintChar
  378.  
  379.     move.w    Paging,d0     pagination on ?
  380.     beq    .Loop         no
  381.     move.w    PageLines,d0     end of    page yet ?
  382.     cmpi.w    #60,d0
  383.     bls    .Loop         no
  384.  
  385.     move.b    #$0C,d1     yes - skip to next page
  386.     bsr    PrintChar
  387.     bra    NewPage
  388.  
  389. .Done    move.w    Paging,d0     pagination on ?
  390.     beq.s    .Done2         no
  391.     move.b    #$0C,d1     yes - send formfeed to    printer
  392.     bsr    PrintChar
  393.  
  394. .Done2    move.w    ImageWriter,d0     is it an ImageWriter ?
  395.     beq.s    .Close         no
  396.     move.b    #$1B,d1     yes - reset it
  397.     bsr    PrintChar
  398.     move.b    #$63,d1
  399.     bsr    PrintChar
  400.     bsr    CloseAbortBox     close the abort/pause dialog
  401.  
  402. .Close    lea    DiskParms,a0     close the file
  403.     _Close
  404. ;
  405. ;*** --> the Driver Manual says you shouldn't Close the serial    driver
  406. ;*** --> and it's correct - the system    hangs if you do!
  407.  
  408. .Exit    bra    SelectionExit
  409.  
  410.  
  411. NulStr    text    #" "
  412. AOutStr text    #".AOut"
  413. BOutStr text    #".BOut"
  414.     align
  415.  
  416. ;****************************************************************
  417. ; User    wants to quit:
  418.  
  419. Quit    bsr    UnhighlightMenu    unhighlight the File title
  420.     rts             return    to the Finder
  421.  
  422. ;****************************************************************
  423. ; Handle a selection in our Style menu:
  424.  
  425. StyleMenu
  426.     move.w    d2,NewStyle     save newly selected style
  427.     moveq    #3,d1         get handle for    the style menu
  428.     bsr    GetMenuHandle
  429. ;                 leaves    handle on stack
  430.     move.w    NewStyle,d1     is it ImageWriter item    ?
  431.     cmp.w    #1,d1
  432.     beq.s    IWItem         yes - special
  433.  
  434.     move.l    (sp),-(sp)     copy of handle    for later
  435.     move.w    StyleNum,-(sp)     remove    check from previous style
  436.     clr.w    -(sp)         FALSE for no check
  437.     _CheckItem
  438. ;                 handle    is on stack
  439.     move.w    NewStyle,-(sp)     put check mark    on new selection
  440.     move.w    #$FFFF,-(sp)     TRUE for a check
  441.     _CheckItem
  442.  
  443.     lea    StyleNum,a0     update    current    style no.
  444.     move.w    NewStyle,(a0)
  445.     bra    SelectionExit
  446.  
  447. ;Handle ImageWriter selection:
  448.  
  449. IWItem    lea    ImageWriter,a0     get current ImageWriter state
  450.     move.w    (a0),d1
  451.     not.w    d1         invert    it
  452.     move.w    d1,(a0)     save new state
  453.     move.w    #1,-(sp)     the item no. of ImageWriter
  454.     move.w    d1,-(sp)     check/uncheck it
  455.     _CheckItem
  456.  
  457. ;Enable/Disable style items:
  458.  
  459.     moveq    #3,d1         get the menu handle
  460.     bsr    GetMenuHandle
  461.     move.l    (sp)+,MenuHandle     save it
  462.     moveq    #3,d3         init to first style item
  463.  
  464. IWLoop    move.l    MenuHandle,-(sp)     pass the handle
  465.     move.w    d3,-(sp)         and the item no.
  466.     move.w    ImageWriter,d0     enabling or disabling ?
  467.     bne.s    IW2         enabling
  468.  
  469.     _DisableItem         else disabling
  470.     bra.s    IW4
  471.  
  472. IW2    _EnableItem
  473.  
  474. IW4    addq.w    #1,d3         to next style item
  475.     cmpi.w    #11,d3         until all styles done
  476.     blt    IWLoop
  477.  
  478.     bra    SelectionExit
  479.  
  480. ;****************************************************************
  481. ; Handle a selection in our Options menu:
  482.  
  483. OptionMenu
  484.     move.w    d2,NewOption     save new option selection no.
  485.     cmpi.w    #3,d2         is it a port option ?
  486.     bge.s    OptionLF     no
  487.  
  488. OptionPort
  489.     moveq    #4,d1         get handle for    option menu
  490.     bsr    GetMenuHandle
  491. ;                 handle    is on stack
  492.     move.l    (sp),-(sp)     another copy of handle    for later
  493.     move.w    PortNum,-(sp)     uncheck the old port selection
  494.     clr.w    -(sp)
  495.     _CheckItem
  496. ;                 handle    still on stack
  497.     move.w    NewOption,-(sp)    check the new port selection
  498.     move.w    #$FFFF,-(sp)
  499.     _CheckItem
  500.  
  501.     lea    PortNum,a0     save new port no.
  502.     move.w    NewOption,(a0)
  503.     bra    SelectionExit     and done
  504.  
  505. OptionLF
  506.     cmpi.w    #6,d2         is it a LF option ?
  507.     bge    OptionPage     no
  508.     moveq    #4,d1         get handle for    option menu
  509.     bsr    GetMenuHandle       returns it on the stack
  510.     move.w    NewOption,d0     the menu's item no.
  511.     move.w    d0,-(sp)
  512.     lea    AddLF-8,a0     get current state of this option
  513.     lsl.w    #1,d0
  514.     move.w    (a0,d0.w),d3
  515.     not.w    d3         invert    it
  516.     move.w    d3,(a0,d0.w)     update    new state
  517.     move.w    d3,-(sp)     flag to check/uncheck
  518.     _CheckItem
  519. ;
  520.     moveq    #4,d1         get handle on stack again
  521.     bsr    GetMenuHandle
  522.     move.w    NewOption,d1     setup opposite    option in d2
  523.     moveq    #5,d2         assume    we're on 4
  524.     cmpi.w    #4,d1         correct assumption ?
  525.     beq.s    LF2         yes
  526.     moveq    #4,d2         no - on 5, opposite is    4
  527.  
  528. LF2    move.w    d2,-(sp)     opposite item no. to enable/disable
  529.     tst.w    d3         checking or unchecking    ?
  530.     bne.s    LF4         checking
  531.  
  532.     _EnableItem         unchecking, enable opposite option
  533.     bra.s    LF6
  534.  
  535. LF4    _DisableItem         checking, disable opposite option
  536.  
  537. LF6    bra    SelectionExit
  538.  
  539. OptionPage
  540.     cmpi.w    #7,d2         is it pagination option ?
  541.     bne.s    OptionTab     no
  542.     moveq    #4,d1         get the menu handle on    stack
  543.     bsr    GetMenuHandle
  544.     move.w    #7,-(sp)     the menu item no.
  545.     lea    Paging,a0     get current pagination    state
  546. OptionPage2
  547.     move.w    (a0),d0
  548.     not.w    d0         invert    it
  549.     move.w    d0,(a0)     save new state
  550.     move.w    d0,-(sp)     check/uncheck the item
  551.     _CheckItem
  552.     bra    SelectionExit
  553.  
  554. OptionTab
  555.     moveq    #4,d1         get the menu handle on    stack
  556.     bsr    GetMenuHandle
  557.     move.w    #9,-(sp)     the menu item no.
  558.     lea    Tabbing,a0     get current tabbing state
  559.     bra    OptionPage2     then same as pagination
  560.  
  561. ;****************************************************************
  562. ; The mouse was pressed in a system window:
  563.  
  564. SystemWindow
  565.     pea    EventRecord     just pass the event to    the system
  566.     move.l    WindowPtr,-(sp)
  567.     _SystemClick
  568.     bra    WaitForEvent
  569.  
  570. ;****************************************************************
  571. ; Display our abort dialog box:
  572.  
  573. DisplayAbortBox
  574.     clr.l    -(sp)         make space for    dialog handle result
  575.     move.w    #2,-(sp)     get the dialog    from resc file
  576.     pea    Dstorage
  577.     move.l    #-1,-(sp)     put it    in front of all    other windows
  578.  
  579.     _GetNewDialog
  580.  
  581.     move.l    (sp),DialogPtr     save its ptr
  582.     _SetPort         make the dialog the current port
  583.  
  584. ;Deactivate the resume    control:
  585.  
  586.     moveq    #3,d1         get a handle to resume    item's control
  587.     bsr    GetItemHandle
  588.     move.w    #255,-(sp)     deactivate the    item
  589.     _HiliteControl
  590.     rts
  591.  
  592. ;****************************************************************
  593. ; Check for abort actions:
  594. ;   R:    carry set if abort
  595.  
  596. CheckAbort
  597.     bsr    TestAbortEvent     any events in our abort dialog    ?
  598.     beq.s    CAOK         nope
  599.     cmpi.w    #1,d1         is it an abort    ?
  600.     beq.s    Abort         yes - flag it
  601.     cmpi.w    #2,d1         is it pause ?
  602.     bne.s    CAOK         no (should never happen)
  603.  
  604.  ;Handle the pause request:
  605.  
  606.     moveq    #2,d1         deactivate the    pause control
  607.     bsr    GetItemHandle
  608.     move.w    #255,-(sp)
  609.     _HiliteControl
  610.  
  611.     moveq    #3,d1         activate the resume control
  612.     bsr    GetItemHandle
  613.     clr.w    -(sp)
  614.     _HiliteControl
  615.  
  616. PauseLoop
  617.     bsr    TestAbortEvent     wait for an event in our abort    box
  618.     beq    PauseLoop
  619.     cmpi.w    #1,d1         is it abort ?
  620.     beq.s    Abort         yes
  621.  
  622. ;Else it must be resume:
  623.  
  624.     moveq    #3,d1         deactivate the    resume control
  625.     bsr    GetItemHandle
  626.     move.w    #255,-(sp)
  627.     _HiliteControl
  628.  
  629.     moveq    #2,d1         activate the pause control
  630.     bsr    GetItemHandle
  631.     clr.w    -(sp)
  632.     _HiliteControl
  633.  
  634. CAOK    or    d0,d0         clear carry for no abort
  635.     rts
  636.  
  637. Abort    ori.b    #1,CCR         set carry for abort
  638.     rts
  639.  
  640. ;****************************************************************
  641. ; Close the abort dialog box:
  642.  
  643. CloseAbortBox
  644.     move.l    DialogPtr,-(sp)
  645.     _CloseDialog
  646.     rts
  647.  
  648. ;****************************************************************
  649. ; Test    for an event in    our abort/pause    dialog box:
  650. ;   R:    equal set if no    events
  651. ;    d1.w = dialog box item no. which caused    any event
  652.  
  653.     loc
  654. TestAbortEvent
  655.     clr.w    -(sp)         clear space for function result
  656.     move.w    #$FFFF,-(sp)     look for any event
  657.     pea    EventRecord     where to put event result
  658.     _GetNextEvent         any waiting events ?
  659.     move.w    (sp)+,d0
  660.     beq.s    .Exit         nope
  661.  
  662.     clr.w    -(sp)         is the    event in a dialog box ?
  663.     pea    EventRecord
  664.     _IsDialogEvent
  665.     move.w    (sp)+,d0
  666.     beq    .Exit         no
  667.  
  668.     clr.w    -(sp)         is it a hit in    our dialog ?
  669.     pea    EventRecord
  670.     pea    DialogPtr
  671.     pea    ItemHit
  672.     _DialogSelect
  673.     move.w    (sp)+,d0
  674.     beq.s    .Exit         no
  675.  
  676.     move.w    ItemHit,d1     yes - rtn item    no., clr equal
  677.  
  678. .Exit    rts
  679.  
  680. ;****************************************************************
  681. ; Get a handle    to a control item in the abort dialog box:
  682. ;   P:    d1.w = the item    no.
  683. ;   R:    the handle on the stack
  684.  
  685. GetItemHandle
  686.     move.l    DialogPtr,-(sp)
  687.     move.w    d1,-(sp)
  688.     pea    ItemType
  689.     pea    ItemHandle
  690.     pea    ItemBox
  691.     _GetDItem
  692.  
  693.     move.l    (sp)+,a0       ;get    the rtn    address
  694.     move.l    ItemHandle,-(sp)    ;return the handle on the stack
  695.     jmp    (a0)
  696.  
  697. ;****************************************************************
  698. ; Send    the style escape codes to the printer:
  699.  
  700.     loc
  701. StyleToPrinter
  702.     move.w    ImageWriter,d0     no style choice if not    ImageWriter
  703.     beq.s    .Exit
  704.  
  705.     move.b    #$1B,d1        the escape code
  706.     bsr    PrintChar
  707.     lea    StyleEscapes-3,a0    ;the escape    code table
  708.     move.w    StyleNum,d1     current style no.
  709.     move.b    (a0,d1.w),d1     get the style eecape code
  710.     bsr    PrintChar
  711.  
  712. .Exit    rts
  713.  
  714. ;****************************************************************
  715. ; Install a new menu from resource file:
  716. ;   P:    d1.w = menu ID
  717. ;   R:    d1.l = menu handle
  718.  
  719. InstallMenu
  720.     bsr    GetMenuHandle     get the menu's    handle
  721.     move.l    (sp),-(sp)     make another stack copy of handle
  722.     clr.w    -(sp)         beforeID = 0 (after all other others)
  723.     _InsertMenu         insert    the new    menu
  724.     move.l    (sp)+,d1     return    the new    handle
  725.     rts
  726.  
  727. ;****************************************************************
  728. ; Get a menu's    handle:
  729. ;   P:    d1.w = menu no.
  730. ;   R:    (sp).l = the handle
  731.  
  732. GetMenuHandle
  733.     clr.l    -(sp)         space for returned handle
  734.     move.w    d1,-(sp)     menu resource ID
  735.     _GetRMenu         go get    it
  736.     move.l    (sp)+,d1     get the handle    off stack
  737.     move.l    (sp)+,a0     get return address too
  738.     move.l    d1,-(sp)     restack the handle
  739.     jmp    (a0)         and return
  740.  
  741. ;****************************************************************
  742. ; Unhighlight any highlighted menu title:
  743.  
  744. UnhighlightMenu
  745.     clr.w    -(sp)
  746.     _HiliteMenu
  747.     rts
  748.  
  749. ;****************************************************************
  750. ;
  751.  
  752. Beep    move.w    #1,-(sp)
  753.     _SysBeep
  754.     movea.l    #120,a0
  755.  
  756.     _Delay
  757.     rts
  758.  
  759. ;****************************************************************
  760. ; Read    a byte from the    input file:
  761. ;   R:    d1.b = the byte
  762. ;    carry set if any errors
  763.  
  764.     loc
  765. ReadByte
  766.     lea    DiskParms,a0     setup ptr to param blk
  767.     lea    ByteBuffer,a1     specify a buffer
  768.     move.l    a1,ioBuffer
  769.     move.l    #1,ioByteCount     read one byte at a time
  770.  
  771.     clr.w    ioPosMode     relative to current mark
  772.     _Read             read it
  773.  
  774.     move.b    ByteBuffer,d1     return    the byte
  775.     tst.w    d0         any errors ?
  776.     bne.s    .Err         yes
  777.     or    d1,d1         else clear carry
  778.     rts
  779.  
  780. .Err    ori.b    #1,CCR         set carry
  781.     rts
  782.  
  783. ;****************************************************************
  784. ; Print a character:
  785. ;   P:    d1.b = the character
  786.  
  787.     loc
  788. PrintChar
  789.     move.w    StripLF,d0     stripping LF's    ?
  790.     beq.s    .2         no
  791.     cmpi.b    #$0A,d1        yes - is it a LF ?
  792.     beq.s    .Exit         yes - ignore it
  793.  
  794. .2    cmpi.b    #$09,d1         is it a tab ?
  795.     bne.s    .8         no
  796.     move.w    Tabbing,d0     yes - are we expanding    tabs ?
  797.     beq.s    .8         no
  798.  
  799. ;Expand tabs to stops on every    8 columns:
  800.  
  801. .4    move.b    #$20,d1        print a space
  802.     bsr    PrintByte
  803.     move.w    Column,d0     on an 8th column yet ?
  804.     andi.b    #$07,d0
  805.     bne    .4         not yet
  806.     bra.s    .Exit         yes - done
  807.  
  808. .8    move.w    d1,-(sp)     save the char a minute
  809.     jsr    PrintByte     print it
  810.     move.w    (sp)+,d1     get char back
  811.  
  812.     cmpi.b    #$0D,d1        is it a CR ?
  813.     bne.s    .Exit         no
  814.     addq.w    #1,PageLines     yes - count lines
  815.     clr.w    Column         reset column no.
  816.  
  817.     move.w    AddLF,d0     adding    LF's to    CR's ?
  818.     beq.s    .Exit         no
  819.     move.b    #$0A,d1        yes - add a LF
  820.     bsr    PrintByte
  821.  
  822. .Exit    rts
  823.  
  824. ;****************************************************************
  825. ; Print a byte:
  826. ;   P:    d1.b = the byte
  827.  
  828.     loc
  829. PrintByte
  830.     lea    PrtOutParms,a0     setup ptr to param blk
  831.     lea    ByteBuffer,a1     specify a buffer
  832.     move.l    a1,ioBuffer
  833.     move.b    d1,(a1)        put the byte in the buffer
  834.     move.l    #1,ioByteCount     write one byte    at a time
  835.  
  836.  
  837.     cmpi.b    #$0D,d1        bump column if    not CR or LF
  838.     beq.s    .2
  839.     cmpi.b    #$0A,d1
  840.     beq.s    .2
  841.     addq.w    #1,Column     else bump column no.
  842.  
  843. .2    move.w    PortNum,d0
  844.     cmpi.w    #2,d0
  845.     beq.s    OSPRTK
  846.     _Write
  847.     rts
  848.  
  849. ; ==> This stuff in upper case    was added so that List would work
  850. ; ==> under the FastFinder. It's not needed under Apple's Finder.
  851. ; ==> It goes right to    the SCC    chip to    monitor    the CTS    line because
  852. ; ==> characters were dropping    under FastFinder!
  853.  
  854. OSPRTK    MOVEM.L    D1-D2/A0,-(SP)
  855.     MOVE.L    #$9FFFF8,A0
  856.  
  857.     MOVE.B    (A0),D2
  858.  
  859. OSPRT2    ADD.L    #$200001,A0
  860.  
  861.     MOVE.B    #0,(A0)
  862.     MOVE.W    (A7),(A7)
  863.     MOVE.B    #$10,(A0)
  864.     SUB.L    #$200001,A0
  865.  
  866.     MOVE.B    (A0),D2        DO WE HAVE CTS    ?
  867.     BTST    #5,D2
  868.     BNE.S    OSPRT2         NO - PRINTER IS BUSY
  869.  
  870.     MOVE.B    (A0),D2
  871. OSD2    MOVE.W    (A7),(A7)
  872.     MOVE.B    (A0),D2
  873.     BTST    #2,D2         TX EMPTY ?
  874.     BEQ.S    OSD2         NO - WAIT
  875.  
  876.     MOVE.L    A0,-(SP)
  877.     ADD.L    #$200001,A0
  878.  
  879.     MOVE.B    D1,4(A0)
  880.     MOVE.L    (SP)+,A0
  881.  
  882.     MOVE.B    (A0),D2        WAIT FOR CHAR TO GET OUT
  883. OSD4    MOVE.W    (A7),(A7)
  884.     MOVE.B    (A0),D2
  885.     BTST    #2,D2
  886.     BEQ.S    OSD4
  887.  
  888.     MOVE.B    (A0),D2
  889.     MOVEM.L    (SP)+,D1-D2/A0
  890.     RTS
  891.  
  892. ;****************************************************************
  893. ; Table of escape codes to ImageWriter    for various styles:
  894.  
  895. StyleEscapes
  896.     dc.b    $6E,$4E,$45,$70
  897.     dc.b    $50,$65,$71,$51
  898.  
  899. ;****************************************************************
  900. ; Initialized data storage area:
  901.  
  902. ImageWriter    dc.w    $FFFF     true or false
  903. StyleNum    dc.w    9     current print style no.
  904.  
  905. PortNum        dc.w    2     1 = port A, 2 = port B
  906. AddLF        dc.w    $FFFF     true or false
  907. StripLF        dc.w    0     true or false
  908. Paging        dc.w    $FFFF     pagination - true or false
  909. Tabbing        dc.w    $FFFF     tab expansion - true or false
  910.  
  911. ;****************************************************************
  912.  
  913. ;This is the resource portion of the LIST application.    It uses
  914. ;the in-line resource compiling capabilities of McAsm.
  915.  
  916. ;****************************************************************
  917. ;Some equates we'll need:
  918.  
  919. chk        equ    $12         check mark char
  920. visible        equ    $FFFF         true boolean
  921. nogoaway    equ    0         false boolean
  922.  
  923. ;DITL types:
  924.  
  925. button        equ    4
  926. statictext    equ    8
  927.  
  928. ;****************************************************************
  929. ;Version data is a string whose type is the signature of the
  930. ;application -    we have    to define our own resource for this 'cause
  931. ;it's a non-standard type:
  932.  
  933. ; ('[[...]]' are McAsm's user defined resource    delimiters.)
  934.  
  935.  
  936. [[ LIST,0            ID is 0 by convention,    no attr    or name
  937.     text    #"Lister, V1.1, 7-12-85"
  938. ]]
  939.  
  940. ;****************************************************************
  941. ;All the rest are standard resource types:
  942.  
  943. ; ('$$' is McAsm's delimiter for a standard resource definition.)
  944.  
  945. ;****************************************************************
  946. ;Tell the Finder that we have bundle info in this application:
  947.  
  948. $$ BNDL,128             bundle    resc, ID = 128
  949. LIST                 the application's signature again
  950. 0                 ID is again 0 by convention
  951. 2                 two resc types    in the BNDL list:
  952. ICN#,1                 map one icon list:
  953. 0,128                 local ID 0 -> actual ID 128
  954. FREF,1                 map one FREF list:
  955. 0,128                 local ID 0 -> actual ID 128
  956.  
  957. ;****************************************************************
  958. ;Our bundle's FREF resource:
  959.  
  960. $$ FREF,128             FREF resc, ID = 128
  961. APPL                 filetype
  962. 0                 local ID for icon list
  963. |                 no filename follows the application
  964.  
  965. ;****************************************************************
  966. ;This is our unique desktop icon and it's selected mask. To get
  967. ;this to display, we'll have to set the 'bundle bit' in the final
  968. ;linked file and then re-init the desktop by holding down the command
  969. ;and option keys as we    execute    the Finder. (FEDIT or something
  970. ;similar can be used to set the bundle    bit.)
  971.  
  972. $$ ICN#,128             an icon list, ID = 128
  973.  
  974. $00000000,$00000000,$1FE00000,$20100000
  975. $2FD00000,$28500000,$28500000,$2FD00000
  976. $20100000,$3FF00000,$20100000,$21DC3F80
  977. $201460C0,$2014C030,$3FF48018,$000D800C
  978. $01F901E6,$06010323,$1803FFF1,$301E03B1
  979. $20F00E31,$23001839,$33FFF029,$1E00102D
  980. $0200D065,$0200D1C6,$02001301,$02001C00
  981. $03FFF800,$00000000,$3FF80000,$7FF80000
  982. $00000000,$1FF00000,$3FF80000,$7FF80000
  983. $7FF80000,$7FF80000,$7FF80000,$7FF80000
  984. $7FF80000,$7FF80000,$7FFE3F80,$7FFE7FC0
  985. $7FFEFFF0,$7FFFFFF8,$7FFFFFFC,$7FFFFFFE
  986. $07FFFFFF,$1FFFFFFF,$3FFFFFFF,$7FFFFFFF
  987. $7FFFFFFF,$7FFFFFFF,$7FFFFFFF,$3FFFFFFF
  988. $1FFFFFFF,$07FFFFEF,$07FFFFC7,$07FFFF01
  989. $07FFFC00,$07FFF800,$00000000,$00000000
  990.  
  991. ;****************************************************************
  992. ;This is our 'About' menu:
  993.  
  994. $$ MENU,1             menu ID 1
  995. 0,0,0                 placeholders for some stuff
  996. $FFFFFFFB             enable    mask - item 2 disabled
  997. "/$14"                 menu title = apple char
  998. 2                 two items in this menu:
  999. ;                 item 1:
  1000. About List...               the menu item
  1001. 0,0                   no icon, no keybd equivalent
  1002. 0,0                   no marking char, text style = plain
  1003. ;                 item 2:
  1004. -------------               the item - draw a disabled line
  1005. 0,0,0,0               no icon, no kybd, no    mark, plain text
  1006.  
  1007. ;This is our 'File' menu:
  1008.  
  1009. $$ MENU,2             menu ID 2
  1010. 0,0,0                 placeholders for some stuff
  1011. $FFFFFFFF             enable    mask - everything enabled
  1012. File                 menu title
  1013. 2                 two items in this menu:
  1014. ;                 item 1:
  1015. Listing               the menu item
  1016. 0,0,0,0               no icon, no kybd, no    mark, plain text
  1017. ;                 item 2:
  1018. Quit                   the menu item
  1019. 0,0,0,0               no icon, no kybd, no    mark, plain text
  1020.  
  1021.  
  1022. ;****************************************************************
  1023. ;This is our 'Style' menu:
  1024.  
  1025. $$ MENU,3             menu ID 3
  1026. 0,0,0                 placeholders for some stuff
  1027. $FFFFFFFB             enable    mask - everything enabled but item 2
  1028. Style                 menu title
  1029. 10                 ten items in this menu:
  1030. ;                 item 1:
  1031. ImageWriter               the menu item
  1032. 0,0,chk,0               no icon, no kybd, check mark, plain text
  1033. ;                 item 2:
  1034. --------------------           disabled line
  1035. 0,0,0,0               no icon, no kybd, no    mark, plain text
  1036. ;                 item 3:
  1037. Extended    72           the item
  1038. 0,0,0,0               nothing special
  1039. ;                 item 4:
  1040. PICA        80
  1041. 0,0,0,0
  1042. ;                 item 5:
  1043. ELITE           96
  1044. 0,0,0,0
  1045. ;                 item 6:
  1046. PICA prop.    --
  1047. 0,0,0,0
  1048. ;                 item 7:
  1049. ELITE prop.   --
  1050. 0,0,0,0
  1051. ;                 item 8:
  1052. Semicond.   108
  1053. 0,0,0,0
  1054. ;                 item 9:
  1055. Condensed  120
  1056. 0,0,chk,0               check mark on this one
  1057. ;                 item 10:
  1058. Ultracond.   132
  1059. 0,0,0,0
  1060.  
  1061.  
  1062. ;****************************************************************
  1063. ;This is our 'Options'    menu:
  1064.  
  1065. $$ MENU,4             menu ID 4
  1066. 0,0,0                 placeholders for some stuff
  1067. $FFFFFE97             enable    mask - 3,5,6,8 disabled
  1068. Options             menu title
  1069. 9                 nine items in this menu:
  1070. ;                 item 1:
  1071. Port A, modem               the menu item
  1072. 0,0,0,0               no icon, no kybd, no    mark, plain text
  1073. ;                 item 2:
  1074. Port B, printer           the item
  1075. 0,0,chk,0               check mark on this one
  1076. ;                 item 3:
  1077. -------------------           another disabled line
  1078. 0,0,0,0               nothing special
  1079. ;                 item 4:
  1080. Add LFs to CRs               the item
  1081. 0,0,chk,0               another check mark
  1082. ;                 item 5:
  1083. Strip LFs               this    one's disabled
  1084. 0,0,0,0
  1085. ;                 item 6:
  1086. -------------------           another disabled line
  1087. 0,0,0,0
  1088. ;                 item 7:
  1089. Pagination, 60    lppg           the item
  1090. 0,0,chk,0               and yet another check mark
  1091. ;                 item 8:
  1092. -------------------           yet another disabled    line
  1093. 0,0,0,0
  1094. ;                 item 9:
  1095. Expand tabs, 8 spcs
  1096. 0,0,chk,0               check mark on this one
  1097.  
  1098. ;****************************************************************
  1099. ;This is the 'About' dialog box:
  1100.  
  1101. $$ DLOG,1             dialog, ID = 1
  1102. 100,100,190,400         bounds    rectangle
  1103. 1                 type =    modal dialog box
  1104. visible             initial state
  1105. nogoaway             no close box
  1106. 0                 refcon
  1107. 1                 resc ID of DLOG's item    list
  1108. |                 no title
  1109.  
  1110. $$ DITL,1             item list for above
  1111. 3                 three items in    this list:
  1112. ;                 item 1:
  1113. 0                   handle holder
  1114. 15,20,36,300               display rectangle
  1115. statictext               item    type
  1116. All I wanted was a listing...       the item
  1117. ;                 item 2:
  1118. 0                   handle holder
  1119. 35,20,56,300               display rectangle
  1120. statictext               item    type
  1121. "     By Dave McWherter"       the item
  1122. ;                 item 3:
  1123. 0                   handle holder
  1124. 60,230,80,290               display rectangle
  1125. button                   item    type
  1126. OK                   button's title
  1127.  
  1128. ;****************************************************************
  1129. ;This is the 'Change your mind?' dialog box:
  1130.  
  1131. $$ DLOG,2             dialog, ID = 2
  1132. 100,100,220,235         bounds    rectangle
  1133. 1                 type =    modal dialog box
  1134. visible             initial state
  1135. nogoaway             no close box
  1136. 0                 refcon
  1137. 2                 resc ID of DLOG's item    list
  1138. Change    your mind?         the title
  1139. $$ DITL,2             item list for above
  1140. 3                 three items in    this list:
  1141. ;                 item 1:
  1142. 0                   handle holder
  1143. 15,20,35,95               display rectangle
  1144. button                   item    type
  1145. Abort                   button's title
  1146. ;                 item 2:
  1147. 0                   handle holder
  1148. 50,20,70,95               display rectangle
  1149. button                   item    type
  1150. Pause                   button's title
  1151. ;                 item 3:
  1152. 0                   handle holder
  1153. 85,20,105,95               display rectangle
  1154.  
  1155. button                   item    type
  1156. Resume                   button's title
  1157.  
  1158.  
  1159. ;****************************************************************
  1160.  
  1161.     end
  1162.